adding consecutive number to userform textbox

i've got a sample database (attached) with a userform for inputting of data. What i want it to do is automatically generate the next number and add it to textbox "our ref" on the userform. the number is in Col C. This is the code i've tried using the code highlighted in red which doesnt work..... can you point me in the right direction ?

i've attached said file...

Private Sub UserForm_Initialize()
Application.ScreenUpdating = False
Worksheets("DATA").Select
Range("A2").Select
Do Until ActiveCell.Value = ""
    UserForm1.ComboBox1.AddItem ActiveCell.Value
    ActiveCell.Offset(1, 0).Select
Loop

Worksheets("DATA").Select
Range("B2").Select
Do Until ActiveCell.Value = ""
    UserForm1.ComboBox2.AddItem ActiveCell.Value
    ActiveCell.Offset(1, 0).Select
Loop

Worksheets("DATA").Select
Range("c2").Select
Do Until ActiveCell.Value = ""
    UserForm1.ComboBox3.AddItem ActiveCell.Value
    ActiveCell.Offset(1, 0).Select
Loop
Worksheets("RESULTS").Select
Range("C1").Select
nextNumber = Sheets("RESULTS").Range("C1").Value + 1

    UserForm1.TextBox3.AddItem nextNumber.Value
    
  
    Loop
    
Worksheets("Results").Select
End Sub

You don't need all those Loops nor Selections. Change the initialize code to

Private Sub UserForm_Initialize()
    Application.ScreenUpdating = False
    With Worksheets("DATA")
        UserForm1.ComboBox1.List = .Range(.Cells(2, 1), .Cells(.Rows.Count, 1).End(xlUp)).Value
        UserForm1.ComboBox2.List = .Range(.Cells(2, 2), .Cells(.Rows.Count, 2).End(xlUp)).Value
        UserForm1.ComboBox3.List = .Range(.Cells(2, 3), .Cells(.Rows.Count, 3).End(xlUp)).Value
    End With
    nextnumber = Sheets("RESULTS").Range("C1").Value + 1
    UserForm1.TextBox3.Value = nextnumber    'ActiveCell.Value + 1
End Sub

Please don't use colours and large font in your code as above it is not helping us read it!

A TextBox does not have an additem method.

Search the Forum for some examples of userforms or look at the databaseform example here

http://www.excel-it.com/vba_examples.htm

I think this is what you are trying to do

Private Sub UserForm_Initialize()
Dim nextnumber As Long
Dim rNumbers As Range

Set rNumbers = Sheets("RESULTS").Range(Cells(3, 3), Cells(Rows.Count, 3).End(xlUp))
    Application.ScreenUpdating = False
    With Worksheets("DATA")
        UserForm1.ComboBox1.List = .Range(.Cells(2, 1), .Cells(.Rows.Count, 1).End(xlUp)).Value
        UserForm1.ComboBox2.List = .Range(.Cells(2, 2), .Cells(.Rows.Count, 2).End(xlUp)).Value
        UserForm1.ComboBox3.List = .Range(.Cells(2, 3), .Cells(.Rows.Count, 3).End(xlUp)).Value
    End With
    nextnumber = Application.WorksheetFunction.Max(rNumbers) + 1
    MsgBox nextnumber
    UserForm1.TextBox3.Value = nextnumber    'ActiveCell.Value + 1
End Sub

Just my opinion but I would definitely lose the greenn background of the userform

Your original numbers in Column C do not appear to be recognised as numbers, I had to type them in again.