Modify to Run On Specific Column and Remove trailing digits in string

I have a sheet that has an identifier like 1325686468.2958 on each line of column H. The digits leading up to the "." are the one's that matter to me. I need to keep 1 entry for each unique identifier. I have a macro that I picked up that deletes the entire row based on duplicates in the selected column which is great but I need it modified to first eliminate the 4 trailing digits. Also, this identifier will always be in column H, can i make it run there everytime instead of having to select that column first? Any help would be greatly appciated.

Sub RemoveDupes2()
Dim LR As Long
Dim COL As Long

COL = ActiveCell.Column
LR = Cells(Rows.Count, COL).End(xlUp).Row

With Range(Cells(1, Columns.Count), Cells(LR, Columns.Count))
    .FormulaR1C1 = "=IF(COUNTIF(R1C" & COL & ":RC" & COL & ",RC" & COL & ")=COUNTIF(C" & COL & ",RC" & COL & "), 1, """")"
    .SpecialCells(xlCellTypeFormulas, 2).EntireRow.Delete xlShiftUp
    .ClearContents
End With

End Sub

Try this on a copy of your data:

Option Explicit

Sub RemoveDupes3()
Dim LR As Long

LR = Range("H" & Rows.Count).End(xlUp).Row

With Range(Cells(1, Columns.Count), Cells(LR, Columns.Count))
    .FormulaR1C1 = "=INT(RC8)"
    .Copy
    Range("H1").PasteSpecial xlPasteValues
    .FormulaR1C1 = "=IF(COUNTIF(R1C8:RC8, RC8) = COUNTIF(C8, RC8), 1, """")"
    .SpecialCells(xlCellTypeFormulas, 2).EntireRow.Delete xlShiftUp
    .ClearContents
End With

End Sub

Like so:

Option Explicit

Sub RemoveDupes3()
Dim LR As Long

LR = Range("H" & Rows.Count).End(xlUp).Row

With Range(Cells(1, Columns.Count), Cells(LR, Columns.Count))
    .FormulaR1C1 = "=INT(RC8)"
    .Copy
    Range("H1").PasteSpecial xlPasteValues
    .FormulaR1C1 = "=IF(COUNTIF(R1C8:RC8, RC8) = 1, 1, """")"
    .SpecialCells(xlCellTypeFormulas, 2).EntireRow.Delete xlShiftUp
    .ClearContents
End With

End Sub

Awesome. I've modified it just a little because I changed it so the person pulling the report can choose all fields and first it will delete the unneeded columns based on their headers. This now makes column D where all the action happens. One last challenge I'm facing. When it finishes, row 1, which contains my header is also somehow changed. I tried a few things to make it start in Row 2 but I've not been successful. Help is appreciated.

Sub RemoveDupes()
Dim LR As Long
Dim COL As Long

Dim a As Long
Application.ScreenUpdating = False
For a = 25 To 1 Step -1
  Select Case Cells(1, a).Value
    Case "Call flow", "Call type", "Application", "Ringing started", "Call answered", "Call disposition", "Charging plan", "Call cost", "Money unit", "Transfer source", "Transfer destination", "Initially called extension", "Callback CallerID", "Calling card code", "Flow reference extension"
      Cells(1, a).EntireColumn.Delete
  End Select
Next a
Application.ScreenUpdating = True

LR = Range("E" & Rows.Count).End(xlUp).Row

With Range(Cells(1, Columns.Count), Cells(LR, Columns.Count))
    .FormulaR1C1 = "=INT(RC5)"
    .Copy
    Range("E1").PasteSpecial xlPasteValues
    .FormulaR1C1 = "=IF(COUNTIF(R1C5:RC5, RC5) = 1, 1, """")"
    .SpecialCells(xlCellTypeFormulas, 2).EntireRow.Delete xlShiftUp
    .ClearContents
End With

End Sub

Right here:

With Range(Cells(2, Columns.Count), Cells(LR, Columns.Count))

If that takes care of your need, please click EDIT in your original post, click GO ADVANCED and set the PREFIX box to SOLVED.