VBA issue - trying to separate words with CAPITALS from Proper words

Thought it was already there... Anyways, here are the functions:
----------------------- first function -------------------

Option Explicit
Option Compare Binary

Function RemoveCaps(c As Range)
Dim Individual() As String, keeper As String
Dim i As Integer, j As Integer, k As Integer
Dim allCaps As Boolean

Individual = Split(c)
k = 0
For i = 0 To UBound(Individual)
allCaps = True
For j = 1 To Len(Individual(i))
If Not Mid(Individual(i), j, 1) Like "[A-Z]" Then
allCaps = False
keeper = " " & keeper & Individual(i) & " "
Exit For
End If
Next j
Next i
RemoveCaps = Trim(keeper)
End Function

------------------------------------------------ second function ---------------------------


Option Explicit
Option Compare Binary

Function RemoveProper(c As Range)
Dim Individual() As String, keeper As String
Dim i As Integer, j As Integer, k As Integer, m As Integer
Dim allCaps As Boolean

Individual = Split(c)
k = 0
m = 0
For i = 0 To UBound(Individual)
allCaps = False
For j = 1 To Len(Individual(i))
If Not Mid(Individual(i), j, 1) Like "[A-Z]" Then
If Not Mid(Individual(i), j, 1) Like "-" Then
allCaps = True
m = m + 1
Exit For
End If
End If
Next j
Next i
For i = m To UBound(Individual)
allCaps = False
For j = 1 To Len(Individual(i))
If Mid(Individual(i), j, 1) Like "[A-Z]" Then
allCaps = True
keeper = " " & keeper & Individual(i) & " "
End If
Exit For
Next j
Next i
RemoveProper = Trim(keeper)
End Function

Try this

Public Function Convertname(name As String, LastName As Boolean)

    y = Split(name, " ")
    For n = LBound(y) To UBound(y)
        If y(n) = UCase(y(n)) Then
            LastNames = LastNames & y(n) & " "
        Else
            FirstNames = FirstNames & y(n) & " "
        End If
    Next n
    
    LastNames = Left(LastNames, Len(LastNames) - 1)
    FirstNames = Left(FirstNames, Len(FirstNames) - 1)
    
    If LastName = True Then
        Convertname = LastNames
    Else
        Convertname = FirstNames
    End If
    
End Function

Another one...

Option Explicit
Option Compare Binary

Function RemoveProper(c As Range)
    Dim Individual() As String
    Dim i As Integer
    If InStr(c, " ") Then
        Individual = Split(c)
        For i = 0 To UBound(Individual)
            If UCase(Individual(i)) = Individual(i) Then
                RemoveProper = RemoveProper & Individual(i) & " "
            End If
        Next i
        RemoveProper = Trim(RemoveProper)
    Else
        RemoveProper = ""
    End If
End Function
    
Function RemoveCaps(c As Range)
    Dim Individual() As String
    Dim i As Integer
    If InStr(c, " ") Then
        Individual = Split(c)
        For i = 0 To UBound(Individual)
            If WorksheetFunction.Proper(Individual(i)) = Individual(i) Then
                RemoveCaps = RemoveCaps & Individual(i) & " "
            End If
        Next i
        RemoveCaps = Trim(RemoveCaps)
    Else
        RemoveCaps = ""
    End If
End Function

Try

Function RemoveProper(c As String) As String
    With CreateObject("VBScript.RegExp")
        .Global = True
        .Pattern = "\b\-?[A-Z][a-z]+\-?\b"
        RemoveProper = Application.Trim(.Replace(c, ""))
    End With
End Function

Function RemoveCaps(c As String) As String
    With CreateObject("VBScript.RegExp")
        .Global = True
        .Pattern = "\b\-?[A-Z]+\-?\b"
        RemoveCaps = Application.Trim(.Replace(c, ""))
    End With
End Function

Nice jindon.

Thanks....

Thanks guys, but still doesn't work for a particular case:
Jean-Christophe BASSON-LARBI


If the name with capital letters has a "-", it returns all the name. If I replace the - with a space, it works just fine. So, how can we include the "-" in the [A-Z] range?

My bad. Thanks a lot guys. jindon's code works just perfect. It was an error on my end.