How to make excel file auto save to PDF office 2010

Hi everyone
I have workbook I would like to auto save to PDF copy file in different location every time the original file is save maybe some VBA code is this possible ???

Thanks in advance

Shane

Hello Shane,

Add this macro to your ThisWorkbook module. Change the file path and name to what you will be using.

Private Sub Workbook_AfterSave(ByVal Success As Boolean)

    Dim Filename As String
    Dim Filepath As String
    
        Filepath = "C:\Users\Owner\Documents\"
        Filename = Filepath & ThisWorkbook.Name

        If Success Then
            With ThisWorkbook.ExportAsFixedFormat _
                (Type:=xlTypePDF, _
                 Filename:=Filename, _
                 Quality:=xlQualityStandard, _
                 IncludeDocProperties:=True, _
                 IgnorePrintAreas:=True, _
                 OpenAfterPublish:=False)
            End With
        End If
        
End Sub

hi thanks for your help i seem to be get error with this code i have highlighted in the code showing were it say's im getting compile error also having trouble entering a file name to work

cheers
p.s sorry for being a pain

Private Sub Workbook_AfterSave(ByVal Success As Boolean)

    Dim Filename As String
    Dim Filepath As String
    
        Filepath = "C:\Users\Shane\Documents\"
        Filename = Filepath & ThisWorkbook.Name

        If Success Then
            With ThisWorkbook.ExportAsFixedFormat _ ' this line highlights and i get error message ("compile error expected file or variable")
                (Type:=xlTypePDF, _
                 Filename:=Filename, _
                 Quality:=xlQualityStandard, _
                 IncludeDocProperties:=True, _
                 IgnorePrintAreas:=True, _
                 OpenAfterPublish:=False)
            End With
        End If
        
End Sub

Hi,

It works for me if set out as

With ThisWorkbook
        .ExportAsFixedFormat Type:=xlTypePDF, _
        Filename:=Filename1, _
        Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, _
        IgnorePrintAreas:=True, _
        OpenAfterPublish:=False
    End With

i.e. without the parentheses either side of the .Export......code and with the .Export.... as a new line

Should be:

With ThisWorkbook
        .ExportAsFixedFormat _
        Type:=xlTypePDF, _
        Filename:=Filename1, _
        Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, _
        IgnorePrintAreas:=True, _
        OpenAfterPublish:=False
    End With

Besides, if you set a print area, make sure to set "IgnorePrintAreas" to "False".

Last, but not least, I combined some code I found elsewhere with the code in this forum. That way my PDF file saves in the same location as the Excel file without having to set the path, manually. Next to that, the PDF file only contains the print area of the active worksheet, instead of the whole Excel file :

Private Sub Workbook_AfterSave(ByVal Success As Boolean)
Dim ws As Worksheet
Dim strPath As String
Dim myFile As Variant
Dim strFile As String

Set ws = ActiveSheet

'enter name and select folder for file
' start in current workbook folder
strFile = Replace(ThisWorkbook.Name, ".xlsm", "") _
            & ".pdf"
strFile = ThisWorkbook.Path & "\" & strFile

If Success Then
    ws.ExportAsFixedFormat _
        Type:=xlTypePDF, _
        Filename:=strFile, _
        Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, _
        IgnorePrintAreas:=False, _
        OpenAfterPublish:=False

End If

exitHandler:
    Exit Sub
End Sub