app script not working with only one sheet

I have this app script, it must give two date monthly and yearly. I have 3 sheets that I am using it on "Centus" "Plus" and "Bounty".
I do not understand why it will not work on "Plus" as everything is the same as the two others.

Sample sheet
https://docs.google.com/spreadsheets...it?usp=sharing

and getting this error.
TypeError: Cannot read properties of undefined (reading 'getColumn')
at calculateSumOnCellChange(Code:5:19)

Please Login or Register  to view this content.

How are you running the script?

are you running it yourself in the Apps Script editor?

or do you have some kind of trigger setup?

For others to be able to give relevant help you need to give clear and detailed description of the situation.

Just for fun, i thought i would play with a copy of the file, and instead of using apps scripts to apply formulas (i dont know why you have taken this approach), i have written the following formulas.

To test them out, make a copy of your file, then go to the Centus sheet, and clear out all of the following columns of all their formulas and headings:
D, E, F, I, J, K, L, M, N, O.

Then put these formulas into the respective columns headers (except columns M and N which are redundant)... but do NOT drag them down.. they will autopopulate the results.

={"C Totaal Munte";MAP(A2:A,B2:B,lambda(timestamp,amount,IF(timestamp="",,sum(B2:amount))))}

={"C $ totaal van munte";ARRAYFORMULA(IF(LEN(A2:A),D2:D*G2:G,))}

={"C $ Ontvang vandag";ARRAYFORMULA(IF(LEN(A2:A),B2:B*G2:G,))}

={"C $ per Maand";BYROW(A2:A,LAMBDA(timestamp,IF(LEN(timestamp),SUMIFS(F:F, ARRAYFORMULA(MONTH(A:A)), MONTH(timestamp)),)))}

={"C R Per Maand";ARRAYFORMULA(IF(LEN(A2:A),I2:I*GOOGLEFINANCE("CURRENCY:USDZAR"),))}

={"C $ Per Jaar";BYROW(A2:A,LAMBDA(timestamp,IF(LEN(timestamp),SUMIFS(F:F, ARRAYFORMULA(YEAR(A:A)), YEAR(timestamp)),)))}

={"C R Per Jaar";ARRAYFORMULA(IF(LEN(A2:A),K2:K*GOOGLEFINANCE("CURRENCY:USDZAR"),))}

={"C R toetaal";ARRAYFORMULA(IF(LEN(A2:A),E2:E*GOOGLEFINANCE("CURRENCY:USDZAR"),))}

Hi janmorris

Thank you, It is working

I have used app script as someone told me to use it as thunkable will not werk with formulas that I needed in some column, but he was wrong, it is working 100%

Can you explain only one to me , on what it do
={"C Totaal Munte";MAP(A2:A,B2:B,lambda(timestamp,amount,IF(timestamp="",,sum(B2:amount))))}

Hi hendrikbaz,

={
"C Totaal Munte" = the header
;
MAP(A2:A,B2:B, = the arrays we want to treat by each row
lambda(timestamp,amount, = the names we apply to the values in each row of the range
IF(timestamp="",, = if the "timestamp" cell is blank, then be nothing
sum(B2:amount) = else sum from B2 to the row of the current value of the "amount" (in column B)
)))}

In my testing, the formula works.

If you want help within the file then you will need to share a copy of it with editor access enabled so that we can look directly at the problem.

The curent rate of USDZAR is 18.7671

Attachment 835210

Can you please explain how it is failing?