Fix change event code to add todays date when data is added to multiple cells in column

I have some Change event code which among other things adds todays date into D when data is first entered into G.
The issue I'm having is when I paste data into more than one G cell at the same time it doesn't work. How can I fix this?

Private Sub Worksheet_Change(ByVal Target As Range)

If Intersect(Target, Range("A6:K" & Cells(Rows.Count, "A").End(xlUp).Row)) Is Nothing Or Target.Cells.Count > 1 Then Exit Sub

Application.EnableEvents = False
    Target.WrapText = True
    Target.Rows.AutoFit
Application.EnableEvents = True


    If Target.Cells.Count > 1 Then Exit Sub

    Application.EnableEvents = False

    If Not Intersect(Target, Columns("G")) Is Nothing Then
        If Not IsEmpty(Target) Then
            Target.Offset(, -3).Value = Date
        Else
            Target.Offset(, -3).ClearContents
        End If
    End If

    Application.EnableEvents = True
    

On Error Resume Next
If Intersect(Target, Range("G6:G1048576")) Is Nothing _
Or Target.Cells.Count > 1 _
Or Target.Value = vbNullString Then Exit Sub

If Target.Offset(0, -1).Value = vbNullString Then
    Beep
    NewItem.Show

End If

    If Target.Cells.Count > 1 Then Exit Sub
     
    If Not Intersect(Target, Range("G2:G" & Cells(Rows.Count, "D").End(xlUp).Row)) Is Nothing Then
        If Target.Value = vbNullString Then
            Range("D" & Target.Row) = vbNullString
        End If
    End If

End Sub

Here:

Target.Cells.Count > 1

you force the procedure to quit if there is more than 1 changed cell. change it to:

If Intersect(Target, Range("A6:K" & Cells(Rows.Count, "A").End(xlUp).Row)) Is Nothing then Exit Sub

few lines later it is again (useless, because if the condition were met it would never be executed) so delete:

    If Target.Cells.Count > 1 Then Exit Sub

and ... I am reading with further on several times checking again.

Ok. I'll try to suggest complete final version (no attachment, so not tested)

Private Sub Worksheet_Change(ByVal Target As Range)
dim rng as Range
If Intersect(Target, Range("A6:K" & Cells(Rows.Count, "A").End(xlUp).Row)) Is Nothing Then Exit Sub

Application.EnableEvents = False
Target.WrapText = True
Target.Rows.AutoFit
If Not Intersect(Target, Columns("G")) Is Nothing Then
  for each rng in Intersect(Target, Columns("G")) 
        If Not IsEmpty(rng) Then
            rng.Offset(, -3).Value = Date
        Else
            rng.Offset(, -3).ClearContents
        End If
  next rng
End If
Application.EnableEvents = True

On Error Resume Next
If not Intersect(Target, Range("G6:G1048576")) Is Nothing then
  for each rng in Intersect(Target, Range("G6:G1048576"))
    if rng.Value <> vbNullString and rng.Offset(0, -1).Value = vbNullString Then
        Beep
        NewItem.Show
    End If
  next rng
end if

If Not Intersect(Target, Range("G2:G" & Cells(Rows.Count, "D").End(xlUp).Row)) Is Nothing Then
  for each rng in Intersect(Target, Range("G2:G" & Cells(Rows.Count, "D").End(xlUp).Row)) 
      If rng.Value = vbNullString Then
         Application.EnableEvents = False
         Range("D" & rng.Row) = vbNullString
         Application.EnableEvents = True
      End If
  next rng
End If

End Sub

I wrote it without testing, so check syntax, etc.

Summarizing: As I said - remove all checkin of target.cells.count
In all cases where action on target shall be made cell by cell just do it - for each cell in target (or subset of target) do something.

Thank you Kaper that fixed it.
Im not very experienced when it comes to VB, is there something further that your recommending I do to fix up the code?

Hi,
I am glad it hepled.
I do not really see the point to react on any changes out of column G (the three special cases are all about some change in column G). So may be you could narrow the field here:

If Intersect(Target, Range("A6:K" & Cells(Rows.Count, "A").End(xlUp).Row)) Is Nothing Then Exit Sub

for instance to

If Intersect(Target, Range("G6:G" & Cells(Rows.Count, "A").End(xlUp).Row)) Is Nothing Then Exit Sub

Once you do it (or even if not) here

If Not Intersect(Target, Range("G2:G" & Cells(Rows.Count, "D").End(xlUp).Row)) Is Nothing Then

you start from G2. If the changed range is simply G2 this part will never be executed, because of the first checking whether target intersects with G6:G_last_

So it is probably right to write:

If Not Intersect(Target, Range("G6:G" & Cells(Rows.Count, "D").End(xlUp).Row)) Is Nothing Then

if you do not expect that

Cells(Rows.Count, "D").End(xlUp).Row

is different (lower row number) than

Cells(Rows.Count, "A").End(xlUp).Row

which is checked just at the beginning you could change also this part.