+ Reply to Thread
Results 1 to 8 of 8

Extract data from matrix to list according to criteria

  1. #1
    Registered User
    Join Date
    03-30-2017
    Location
    Brazil
    MS-Off Ver
    7
    Posts
    27

    Post Extract data from matrix to list according to criteria

    Hi everyone!

    I'm creating a monthly schedule template for scheduling customer diaries as shown below.
    Basically, I will insert with an "X" the day that the client has an appointment throughout the month.

    1.png

    As I insert an "X" for a given customer on a certain date, I would like the customer's name and date to be automatically listed in another spreadsheet as shown below.
    2.png

    Does anyone have any idea how to come up with this? I tried some combinations with OFFSET, INDEX, MATCH but without success.

    Thanks in advance.
    Attached Files Attached Files

  2. #2
    Valued Forum Contributor
    Join Date
    09-25-2015
    Location
    Milan Italy
    MS-Off Ver
    office 365
    Posts
    990

    Re: Extract data from matrix to list according to criteria

    Plan2


    B2=IFERROR(DATE(YEAR(Plan1!$A$1),MONTH(Plan1!$A$1),INDEX(Plan1!$B$2:$AE$2,SMALL(IF(Plan1!$A$3:$A$12=Plan2!$A2,IF(Plan1!$B$3:$AE$12="X",COLUMN(Plan1!$B$2:$AE$2)-COLUMN(Plan1!$B$2)+1)),COUNTIF(Plan2!$A$2:Plan2!$A2,Plan2!$A2)))),"")

    Control +shift+enter

    copy down

    format b2:b19 as date
    Attached Files Attached Files

  3. #3
    Registered User
    Join Date
    03-30-2017
    Location
    Brazil
    MS-Off Ver
    7
    Posts
    27

    Re: Extract data from matrix to list according to criteria

    Is it possible to load the customer's name automatically as I mark "X" on a date in my calendar?

    Thanks for your help.

  4. #4
    Valued Forum Contributor
    Join Date
    09-25-2015
    Location
    Milan Italy
    MS-Off Ver
    office 365
    Posts
    990

    Re: Extract data from matrix to list according to criteria

    Plan2

    A2=IFERROR(INDEX(Plan1!$A$3:$A$12,SMALL(IF(Plan1!$B$3:$AE$12="x",ROW(Plan1!$A$3:$A$12)-ROW(Plan1!$A$3)+1),ROWS(Plan1!$A$3:Plan1!A3))),"")

    Control+shift+enter

    Copy down
    Attached Files Attached Files
    Last edited by CARACALLA; 06-05-2020 at 11:03 AM.

  5. #5
    Valued Forum Contributor Eastw00d's Avatar
    Join Date
    02-29-2020
    Location
    Breda, NL
    MS-Off Ver
    2016
    Posts
    754

    Re: Extract data from matrix to list according to criteria

    Hi, I couldn't resist to adapt your CSE functions in regular ones:
    Excel 2016 (Windows) 64 bit
    A
    B
    1
    Customer
    Date
    2
    =IFERROR(INDEX(Plan1!$A$3:$A$12,AGGREGATE(15,6,ROW(Plan1!$A$3:$A$12)-ROW(Plan1!$A$3)+1/(Plan1!$B$3:$AE$12="x"),ROWS($A$2:A2))),"")
    =IFERROR(DATE(YEAR(Plan1!$A$1),MONTH(Plan1!$A$1),INDEX(Plan1!$B$2:$AE$2,AGGREGATE(15,6,COLUMN(Plan1!$B$2:$AE$2)-COLUMN(Plan1!$B$2)+1/((Plan1!$A$3:$A$12=$A2)*(Plan1!$B$3:$AE$12="x")),COUNTIF($A$2:A2,A2)))),"")
    Sheet: Plan2
    Cheers
    Erwin
    I started learning VBA because I was lazy ...
    Still developing.... being more lazy...

  6. #6
    Valued Forum Contributor
    Join Date
    09-25-2015
    Location
    Milan Italy
    MS-Off Ver
    office 365
    Posts
    990

    Re: Extract data from matrix to list according to criteria

    I agree .

    But not knowing the version of Office

    CSE always work

    Regards

  7. #7
    Registered User
    Join Date
    03-30-2017
    Location
    Brazil
    MS-Off Ver
    7
    Posts
    27

    Re: Extract data from matrix to list according to criteria

    Perfect CARACALLA
    Thank you!

  8. #8
    Valued Forum Contributor
    Join Date
    09-25-2015
    Location
    Milan Italy
    MS-Off Ver
    office 365
    Posts
    990

    Re: Extract data from matrix to list according to criteria

    @hpernaf

    If you have office 2010 and later use the formulas

    by EastWood

    Regards

+ Reply to Thread

Thread Information

Users Browsing this Thread

There are currently 1 users browsing this thread. (0 members and 1 guests)

Similar Threads

  1. Replies: 1
    Last Post: 04-15-2020, 12:48 PM
  2. [SOLVED] extract data from list on the basis of multiple criteria
    By sanjuss2 in forum Excel General
    Replies: 4
    Last Post: 11-23-2018, 07:40 AM
  3. want to extract most recent data from a list based on two criteria
    By cnak in forum Excel Formulas & Functions
    Replies: 3
    Last Post: 09-24-2018, 03:31 PM
  4. [SOLVED] Filter and extract list of data based on criteria using INDEX MATCH
    By brake in forum Excel Formulas & Functions
    Replies: 7
    Last Post: 03-13-2018, 08:30 AM
  5. How to extract data with criteria from another sheet and list it.
    By macnabong in forum Excel Formulas & Functions
    Replies: 2
    Last Post: 08-18-2014, 10:10 PM
  6. Extract Data from Matrix
    By woebegone in forum Excel General
    Replies: 12
    Last Post: 08-08-2008, 04:33 PM
  7. How can I extract data from a list that meets certain criteria?
    By fsimek in forum Excel Formulas & Functions
    Replies: 4
    Last Post: 04-28-2008, 04:20 PM

Tags for this Thread

Bookmarks

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts

Search Engine Friendly URLs by vBSEO 3.6.0 RC 1