How to Find the Max and Min Dates from Duplicate Names in a Row and Filter the Names

[elvinayulistia]

Hi all,

I have a data as attached. I have list of repetitive names and dates for each name entry (column A and B).
I would like to filter the duplicate names and pick up the max date and min date for each name.

Appreciate if you could help me formulate the column D, E, and F.

Many thanks!

[TMS]

Try:

=SORT(UNIQUE(FILTER(B3:B33,B3:B33<>"")))
=MINIFS(A3:A33,B3:B33,D3#)
=MAXIFS(A3:A33,B3:B33,D3#)

[elvinayulistia]

Hi TMS,

Thanks for your help. Sorry for not mentioning it earlier, I'm using Excel 2019 so the SORT and UNIQUE function is not available in this version.
Any other suggestion on the formula?

Thanks!

[alansidman]

Here is an alternative solution using Power Query. Your profile indicates you are using O365. Please update your profile to reflect your proper version.

Please Login or Register  to view this content.

Power Query is a free AddIn for Excel 2010 and 2013, and is built-in functionality from Excel 2016 onwards (where it is referred to as "Get & Transform Data").

It is a powerful yet simple way of getting, changing and using data from a broad variety of sources, creating steps which may be easily repeated and refreshed. I strongly recommend learning how to use Power Query - it's among the most powerful functionalities of Excel.

- Follow this link to learn how to install Power Query in Excel 2010 / 2013.

- Follow this link for an introduction to Power Query functionality.

- Follow this link for a video which demonstrates how to use Power Query code provided.

[TMS]

I went with your profile.

=IFERROR(LOOKUP(2,1/(COUNTIF($D$2:D2,B$3:INDEX(B:B,MATCH("zzz",B:B,1)))=0),B$3:B$33),"")
=IF(D3="","",MINIFS($A$3:$A$33,$B$3:$B$33,D3))
=IF(D3="","",MAXIFS($A$3:$A$33,$B$3:$B$33,D3))

All copied down.

[AliGW]

I'm using Excel 2019

Then you need to amend your profile, which says MS365! Misleading information = time wasted for your helpers.

[elvinayulistia]

Hi Alansidman and TMS,

Many thanks for your help and will give it a try!

Hi AliGW,

Sorry for missing to edit my profile. I've changed it to Office 2019 to avoid confusion.
Thanks for highlighting this to me

[AliGW]

That's great - thanks.

[kvsrinivasamurthy]

In E2, F2, G2


=IFERROR(INDEX($B$1:$B$13,AGGREGATE(15,6,ROW($B$3:$B$13)/(ISERROR(MATCH($B$3:$B$13,$D$2:$D2,0))*($B$3:$B$33<>"")),1)),"")

=IF($D3="","",MINIFS($A$3:$A$33,$B$3:$B$33,$D3))

=IF($D3="","",MAXIFS($A$3:$A$33,$B$3:$B$33,$D3))

All copied down

[elvinayulistia]

Hi kvsrinivasamurthy,

I have
Thanks for your help, appreciated.