LinkBack URL
About LinkBacks
Hello,
I have used formula TEXTJOIN and i get duplicated that I need help with removing.
Is there any way to only visualize unique values?
Attached three are examples marked in red where this issue is clear, concerns column G and H.
Hello,
I have used formula TEXTJOIN and i get duplicated that I need help with removing.
Is there any way to only visualize unique values?
Attached three are examples marked in red where this issue is clear, concerns column G and H.
Last edited by caamfin; 07-13-2023 at 02:04 AM.
Try this,
G11
=IF(OR(F11="",F11="3DX-SRMS"),"",(TEXTJOIN(",",TRUE,UNIQUE(IF(F11=Baseline!$A$9:$A$1247,Baseline!$M$9:$M$1247,"")))))
H11
=IF(OR(F11="",F11="3DX-SRMS"),"",(TEXTJOIN(",",TRUE,UNIQUE(IF(F11=Baseline!$A$9:$A$1247,Baseline!$S$9:$S$1247,"")))))
Does adding the UNIQUE function give you the result you expected
=IF(OR(F11="",F11="3DX-SRMS"),"",(TEXTJOIN(",",TRUE,UNIQUE(IF(F11=Baseline!$A$9:$A$1247,Baseline!$M$9:$M$1247,"")))))
I coudnt get this to work as it says #NAME?I will try to add the file again with UNIQUE formula added.Attachment 836367
#NAME suggests it does not recognise the name of a function.
Either mispelled or not available in that version of excel. Are you sure you have O365?
I suppose you didn't translate the formula correct to your own languge.
See attachment for the correct translation of the formulas of windknife and Andy in your language.
Last edited by HansDouwe; 07-14-2023 at 02:16 AM.
UNIQUE nor _xlfn.UNIQUE is available in this excel version it seems, Professional Plus 2019
Are there any workarounds?
It works in the version 365 as you indicated in your profile!
That was in my old work place, i have updated my profile now. Thanks for pointing that out
Question remains though if I can get unique values somehow or if ill have to live them them repeating
Thanks for updating your profile.
This solution works for Excel 2019 (but not for Mac):Formula:
Please Login or Register to view this content.
G11
=IF(OR(F11="",F11="3DX-SRMS"),"",(TEXTJOIN(",",TRUE,IF(ROW($M$9:$M$1247)-8=IF(IF(F11=Baseline!$A$9:$A$1247,Baseline!$M$9:$M$1247,"")="","",MATCH(IF(F11=Baseline!$A$9:$A$1247,Baseline!$M$9:$M$1247,""),IF(F11=Baseline!$A$9:$A$1247,Baseline!$M$9:$M$1247,""),0)),Baseline!$M$9:$M$1247,""))))
commited with Ctrl+Shift+Enter.
H11
=IF(OR(F11="",F11="3DX-SRMS"),"",(TEXTJOIN(",",TRUE,IF(ROW($S$9:$S$1247)-8=IF(IF(F11=Baseline!$A$9:$A$1247,Baseline!$S$9:$S$1247,"")="","",MATCH(IF(F11=Baseline!$A$9:$A$1247,Baseline!$S$9:$S$1247,""),IF(F11=Baseline!$A$9:$A$1247,Baseline!$S$9:$S$1247,""),0)),Baseline!$S$9:$S$1247,""))))
committed with Ctrl+Shift+Enter
Both copied down.
There are currently 1 users browsing this thread. (0 members and 1 guests)
Posting Permissions
Register To Reply
Bookmarks