Upper and Lower Cases of Text

Hi, I need a formula to convert a text in all upper cases into lower cases except for the first letter in the first word after each equal sign. However, the text before the equal sign must still be in capital letters. I currentrly use the function PROPER which did not give me the desired result. Please see attachment.

This is above formula used for the first BUS=BUSINESS, RES=RESIDENTIAL

=UPPER(MID(B2,1,FIND("=",B2)))&PROPER(MID(B2,(FIND("=",B2)+1),(FIND(",",B2)-FIND("=",B2))))&UPPER(MID(B2,FIND(",",B2)+1,FIND("=",B2,(FIND("=",B2)))))&PROPER(MID(B2,FIND("=",B2,(FIND("=",B2))),LEN(B2)+1-FIND("=",B2,FIND("=",B2))))

Without VBA, this would only be possible if you had a fixed number of entries in each cell in Column A (i.e. you had the same number of "=" signs in every cell). Without this knowledge, there is no formula that I am aware of that will accomplish what it is that you are trying to achieve unfortunately.

To achieve the result in VBA, place a button onto your worksheet, and place the following code into your button's Click event (my button is called "CommandButton1"):

Private Sub CommandButton1_Click()
    Dim i, j As Integer
    Dim eqPos() As Integer
    Dim comPos() As Integer
    Dim strRequired As String
    
    'Initialise the array's containing the position of each "=" and ","
    ReDim eqPos(0)
    ReDim comPos(0)
    
    With ActiveSheet
        'Cycle through every populated cell in Column A
        For i = 2 To .Cells(.Rows.Count, "A").End(xlUp).Row
            'Cycle through every character in the cell value
            For j = 1 To Len(.Cells(i, "A").Value)
                If Mid(.Cells(i, "A").Value, j, 1) = "=" Then
                    'If the character is "="
                    ReDim Preserve eqPos(UBound(eqPos) + 1)
                    
                    eqPos(UBound(eqPos)) = j
                End If
                
                If Mid(.Cells(i, "A").Value, j, 1) = "," Then
                    'If the character is ","
                    ReDim Preserve comPos(UBound(comPos) + 1)
                    
                    comPos(UBound(comPos)) = j
                End If
            Next j
            
            'Cycle through every segment of the string, separated by "="
            For j = 1 To UBound(eqPos)
                If j = 1 Then
                    'If this is the first segment
                    If UBound(eqPos) > 1 Then
                        'If this is the first of multiple "="
                        strRequired = Mid(.Cells(i, "A").Value, 1, eqPos(j) + 1)
                    Else
                        'If this is the only "="
                        strRequired = Mid(.Cells(i, "A").Value, 1, eqPos(j) + 1) _
                            & LCase(Mid(.Cells(i, "A").Value, eqPos(j) + 2, Len(.Cells(i, "A").Value) - eqPos(j) - 1))
                    End If
                Else
                    'If this is not the first segment
                    If j < UBound(eqPos) Then
                        'If this is not the last segment
                        strRequired = strRequired _
                            & LCase(Mid(.Cells(i, "A").Value, eqPos(j - 1) + 2, comPos(j - 1) - eqPos(j - 1) - 1)) _
                            & Mid(.Cells(i, "A").Value, comPos(j - 1) + 1, eqPos(j) + 1 - comPos(j - 1))
                    Else
                        'If this is the last segment
                        strRequired = strRequired _
                            & LCase(Mid(.Cells(i, "A").Value, eqPos(j - 1) + 2, comPos(j - 1) - eqPos(j - 1) - 1)) _
                            & Mid(.Cells(i, "A").Value, comPos(j - 1) + 1, eqPos(j) + 1 - comPos(j - 1)) _
                            & LCase(Mid(.Cells(i, "A").Value, eqPos(j) + 2, Len(.Cells(i, "A").Value) - eqPos(j) - 1))
                    End If
                End If
            Next j
            
            'Write the appropriately formatted string to the same row in column D
            .Cells(i, "D").Value = strRequired
            
            'Reset the variables for the next row
            strRequired = ""
            ReDim eqPos(0)
            ReDim comPos(0)
        Next i
    End With
End Sub

Yes, As JBeaucaire says VBA would be the solution.
But if you would like to have a non VBA solution, see if the attached kind of work around helps.

That code was very impressing Sixthsense!!!

Thank you all for your suggestions. For now, I will use the Excel formula since I'm on tight deadline and VBA for the next project.