count with multiple criteria without duplicates based on a different column

You could probably get a single-formula solution, but how about splitting it in two?

One for "paid" and one for "cancelled", and then add them?

You are missing an IF in that version (and all ranges should start from the same row), so formula should be this, assuming range starts at row 7

=SUM(IF(FREQUENCY(IF($H$7:$H$2381>AQ2383,IF($H$7:$H$2381<AQ2384,IF($AD$7:$AD$2381="paid", MATCH($L$7:$L$2381,$L$7:$L$2381,0)))),ROW($L$7:$L$2381)-ROW($L$7)+1),1))

....although you will get an error if any of L7:L2381 are blank so normally you use an extra IF to filter out those rows, like this

=SUM(IF(FREQUENCY(IF($H$7:$H$2381>AQ2383,IF($H$7:$H$2381<AQ2384,IF($AD$7:$AD$2381="paid", IF($L$7:$L$2381<>"",MATCH($L$7:$L$2381,$L$7:$L$2381,0))))),ROW($L$7:$L$2381)-ROW($L$7)+1),1))

and consider "paid" or "cancelled" with this version

=SUM(IF(FREQUENCY(IF($H$7:$H$2381>AQ2383,IF($H$7:$H$2381<AQ2384,IF($AD$7:$AD$2381={"paid","cancelled"}, IF($L$7:$L$2381<>"",MATCH($L$7:$L$2381,$L$7:$L$2381,0))))),ROW($L$7:$L$2381)-ROW($L$7)+1),1))

all formulas need to be confirmed with CTRL+SHIFT+ENTER

Based on your last post in this thread, its apparent that you are satisfied with the solution(s) you've received and have solved your question, but you haven't marked your thread as "SOLVED". I will do it for you this time.

In future, to mark your thread as Solved, you can do the following -
Select Thread Tools-> Mark thread as Solved.

Incase your issue is not solved, you can undo it as follows -
Select Thread Tools-> Mark thread as Unsolved.

Also, since you are relatively new to the forum, i would like to inform you that you can thank those who have helped you by clicking the small star icon located in the lower left corner of the post which helped you. This adds to the reputation of the person who has taken the time to help you.