Hello
I want to create 3 league tables for a production report...
I have 3 shifts AM Shift, PM and a night shift, I want a league table of who is performing the best based on numbers of parts scrapped
COL Z - to return the inspetor and COL AA to show how many parts have been scrapped - i Need this update as the data changes
Please see attached to help undertanding (expected results in orange)
Ideally i need tis in formalua form
Paul
How are you filtering the data for these sums? If it's just on the shift, then I don't think your expected results are correct, so what criteria in other columns need to be met?
Here's a starting point:
=LET(i,K2:K2916,s,P2:P2916,ss,SUMIF(i,i,s),h,HSTACK(i,ss),TAKE(SORT(UNIQUE(FILTER(h,Q2:Q2916="AM Shift")),2,-1),10))
Ali
Enthusiastic self-taught user of MS Excel who's always learning!
Don't forget to say "thank you" in your thread to anyone who has offered you help.
You can reward them by clicking on * Add Reputation below their user name on the left, if you wish.
Forum Rules (updated August 2023): please read them here.
This seems to get closer, but still doesn't match your results:
Which other column do I need to filter on (bit in red)?
Please Login or Register to view this content.
yes, its just on the shift
LET(i,K2:K2916,s,P2:P2916,ss,SUMIF(i,i,s),h,HSTACK(i,ss),TAKE(SORT(UNIQUE(FILTER(h,Q2:Q2916="AM Shift")),2,-1),10))
this seems to work (do i just change "AM Shift" PM to look at the different shift ?
Yes.
This includes the ordinals:
=LET(i,K2:K2916,s,P2:P2916,ss,SUMIF(i,i,s),h,HSTACK(i,ss),HSTACK({"1st";"2nd";"3rd";"4th";"5th";"6th";"7th";"8th";"9th";"10th"},TAKE(SORT(UNIQUE(FILTER(h,Q2:Q2916="AM Shift")),2,-1),10)))
Why did you provide incorrect expected results? That was very misleading!
Glad to have helped.
If that takes care of your original question, please choose Thread Tools from the menu link above and mark this thread as SOLVED.
Also, if you have not already done so, you may not be aware that you can thank anyone who offered you help towards a solution for your issue by clicking the small star icon (* Add Reputation) located in the lower left corner of the post in which the help was given. By doing so you can add to the reputation(s) of each of those who offered help.
appoliges if my expected data was wrong...
i'm confused at the best of times.... I have used your formula, but i dont thing its working correctly,
Please see attached - I think somthing is going wrong when the usser is booking on multilple shifts
Oh - silly error on my part!
Try this (change in red):
=LET(i,K2:K2916,s,P2:P2916,ss,SUMIFS(s,i,i,Q2:Q2916,"AM Shift"),h,HSTACK(i,ss),HSTACK({"1st";"2nd";"3rd";"4th";"5th";"6th";"7th";"8th";"9th";"10th"},TAKE(SORT(UNIQUE(FILTER(h,Q2:Q2916="AM Shift")),2,-1),10)))
So that you only have to change the shift name in one place:
=LET(sh,"AM Shift",i,K2:K2916,s,P2:P2916,ss,SUMIFS(s,i,i,Q2:Q2916,sh),h,HSTACK(i,ss),HSTACK({"1st";"2nd";"3rd";"4th";"5th";"6th";"7th";"8th";"9th";"10th"},TAKE(SORT(UNIQUE(FILTER(h,Q2:Q2916=sh)),2,-1),10)))
perefect
thanks for your time Ali
No problem.
If you have not already done so, you may not be aware that you can thank anyone who offered you help towards a solution for your issue by clicking the small star icon (* Add Reputation) located in the lower left corner of the post in which the help was given. By doing so you can add to the reputation(s) of each of those who offered help.
There are currently 1 users browsing this thread. (0 members and 1 guests)
Posting Permissions
LinkBack URL
About LinkBacks
Register To Reply
Bookmarks