Merging Data Using VLookup !!! Please help

testing_vlookup (2).xlsx
Does this work?
Use version (2)

hi ghaffar3, welcome to the forum. try this in C3 of "Music" sheet:
=IF(ISNA(VLOOKUP($B3,Sheet1!$B$3:C$102,COLUMN(C2)-1,0)),"",VLOOKUP($B3,Sheet1!$B$3:C$102,COLUMN(C2)-1,0))

or in Excel 2007 & above:
=IFERROR(VLOOKUP($B3,Sheet1!$B$3:C$102,COLUMN(C2)-1,0),"")

copy below & across

you're very welcome, ghaffar3. there are 4 parts to the VLOOKUP;
lookup_value
both list should have a common value to look up for. in your case, it's the title ID

table array
this is a range that should contain at least 2 columns. the 1st one must be the column where the lookup_value can be found. the other (might not be 2nd column) should be the column where your desired results are. in your case the 1st column where title ID can be found is Sheet1!B3:B102. what you need to return is the tempo, which is in Sheet1!C3:C102. so the very least your formula should include is:
Sheet1!B3:C102
i hope you are familiar with the dollar signs (absolute & relative cell referencing). the table array are usually fixed in the columns & rows, because it's a fixed place you would want to look up in. but i intentionally omitted the dollar sign for column C because copying from Music!C3 to Music!D3 will then return me column D (where the tempo ID is):
Sheet1!$B$3:D$102
i saw that you had a Named Range "Tempo". it doesnt work because the 1st column is not where the lookup_value is found. but it is also not advisable to put the whole of Sheet1!$B:$D. it will work no doubt. but looking up 1 million over rows is Excel slows things down.

col_index_num
wherever we start our table_array is column 1. counting from there, this number decides which column of the table array we want to return. since Sheet1!B3:B102 is 1, tempo is in Sheet1!C3:C102, so it's 2. tempo ID in Sheet1!D3:D102 is 3. my personal preference is to try use just 1 formula, so instead of typing 2 types of formula (one to return 2 for tempo, 2nd to return 3 for tempo id), i used the COLUMN formula. COLUMN returns the column number of the cell reference. COLUMN(A1) or COLUMN (A1000) returns me 1 because it's in column 1. so if i put COLUMN (C3) or anywhere in C, it'll return me 3. i'm looking for tempo, so i need to return 2. i can just deduct 1 from it.
COLUMN(C2)-1

range_lookup
FALSE or 0 means you are looking for an exact match. i suggest you just stick to this for now.

hope that helps. the ISNA or IFERROR is simply to show other values instead of #N/A when the value cannot be found.