Replace Application.InputBox with a string.

I got this code over the internet, and I modify a bit to fit my needs.
There is one thing I don't really know how to get rip.
I want to replace the application.inputbox part with my own string there. I do not want the user input anymore. However, I do not know really know how to do that part. Can anyone please help.

Sub FilterData()
    Dim ws1Master As Worksheet, wsNew As Worksheet, wsFilter As Worksheet
    Dim Datarng As Range, FilterRange As Range, objRange As Range
    Dim rowcount As Long
    Dim colcount As Integer, FilterCol As Integer, FilterRow As Long
    Dim SheetName As String
    Dim BillAcctID As String
    Dim CellAddress As String

Call GetFile

'look for billing_acct_id col
BillAcctID = Cells.Find(What:="Billing_Acct_ID", After:=ActiveCell, LookIn:=xlValues, LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False).Select

'get the cell address of billing_acct_id col
CellAddress = ActiveCell.Address


    'master sheet
    Set ws1Master = ActiveSheet
    'set the Column you
    'are filtering
    


top:
    On Error Resume Next
    'Set objRange = Application.InputBox("Select Field Name To Filter", "Range Input", CellAddress, , , , , 8)


    
    On Error GoTo 0
    If objRange Is Nothing Then
        Exit Sub
    ElseIf objRange.Columns.Count > 1 Then
        GoTo top
    End If

    FilterCol = objRange.Column
    FilterRow = objRange.Row

    With Application
        .ScreenUpdating = False
        .DisplayAlerts = False
    End With
    On Error GoTo progend
    'add filter sheet
    Set wsFilter = Sheets.Add
    With ws1Master
        .Activate
        .Unprotect Password:=""  'add password if needed
        
        rowcount = .Cells(.Rows.Count, FilterCol).End(xlUp).Row
        colcount = .Cells(FilterRow, .Columns.Count).End(xlToLeft).Column

        If FilterCol > colcount Then
            Err.Raise 65000, "", "FilterCol Setting Is Outside Data Range.", "", 0
        End If

        Set Datarng = .Range(.Cells(FilterRow, 1), .Cells(rowcount, colcount))
        'extract Unique values from FilterCol
        .Range(.Cells(FilterRow, FilterCol), _
               .Cells(rowcount, _
                      FilterCol)).AdvancedFilter _
                      Action:=xlFilterCopy, _
                      CopyToRange:=wsFilter.Range("A1"), _
                      Unique:=True
        rowcount = wsFilter.Cells(wsFilter.Rows.Count, "A").End(xlUp).Row
        
        'set Criteria
        wsFilter.Range("B1").Value = wsFilter.Range("A1").Value
        For Each FilterRange In wsFilter.Range("A2:A" & rowcount)
            'check for blank cell in range
            If Len(FilterRange.Value) > 0 Then
                'add the FilterRange to criteria
                wsFilter.Range("B2").Value = FilterRange.Value
                SheetName = RTrim(Left(FilterRange.Value, 31))
                'if FilterRange sheet exists
                'update it
                If SheetExists(SheetName) Then
                    Sheets(SheetName).Cells.Clear
                Else
                    'add new sheet
                    Set wsNew = Sheets.Add(After:=Worksheets(Worksheets.Count))
                    wsNew.Name = SheetName
                End If
                
                
                Datarng.AdvancedFilter Action:=xlFilterCopy, _
                                       CriteriaRange:=wsFilter.Range("B1:B2"), _
                                       CopyToRange:=Sheets(SheetName).Range("A1"), _
                                       Unique:=False
            End If
        Next
        .Select
    End With
progend:
    wsFilter.Delete
    With Application
        .ScreenUpdating = True
        .DisplayAlerts = True
    End With
    If Err > 0 Then
        MsgBox (Error(Err)), 16, "Error"
        Err.Clear
    End If
    
Call Splitbook

ActiveWorkbook.Close savechanges:=False

Call OpenFile
    
End Sub

E.g.,

Set objRange = Range("A1:D10")