VBA Help to Sort Worksheets

Hi,

Try this code which I had on hand (on my PC)
Adjust as needed...
It will sort from sheet 4 to the end...

Sub SortSheets()
Dim lCount As Long, lCounted As Long
Dim lShtLast As Long
Dim lReply As Long

lReply = MsgBox("To sort Worksheets ascending, select 'Yes'. " & vbNewLine & _
    "To sort Worksheets descending select 'No'", vbYesNoCancel + vbInformation, "Sheet Sort")
If lReply = vbCancel Then Exit Sub
lShtLast = Sheets.Count
    If lReply = vbYes Then 'Sort ascending
        For lCount = 4 To lShtLast
            For lCount2 = lCount To lShtLast
                If UCase(Sheets(lCount2).Name) < UCase(Sheets(lCount).Name) Then
                    Sheets(lCount2).Move Before:=Sheets(lCount)
                End If
            Next lCount2
        Next lCount
    Else 'Sort descending
     For lCount = 4 To lShtLast
            For lCount2 = lCount To lShtLast
                If UCase(Sheets(lCount2).Name) > UCase(Sheets(lCount).Name) Then
                    Sheets(lCount2).Move Before:=Sheets(lCount)
                End If
            Next lCount2
        Next lCount
    End If
End Sub

You could use this macro.
The LT function tests if the sheet name is numeric, to avoid a purely alphabetic sort where "12" < "2"

Sub test()
    Dim Descending As Boolean
    Dim i As Long, j As Long
    Application.ScreenUpdating = False

    Descending = (MsgBox("Sort Ascending?", vbYesNo) = vbNo)
    
    With ThisWorkbook
        For i = 1 To .Sheets.Count - 1
            For j = i + 1 To .Sheets.Count
                If LT(.Sheets(j), .Sheets(i)) Xor Descending Then
                    .Sheets(j).Move after:=.Sheets(i)
                    .Sheets(i).Move after:=.Sheets(j)
                End If
            Next j
        Next i
        
        Sheet3.Move before:=.Sheets(1)
        Sheet2.Move before:=.Sheets(1)
        Sheet1.Move before:=.Sheets(1)
        Application.ScreenUpdating = True
    End With
End Sub

Function LT(aSheet As Worksheet, bSheet As Worksheet) As Boolean
    If IsNumeric(aSheet.Name) Or IsNumeric(bSheet.Name) Then
        LT = Val(aSheet.Name) < Val(bSheet.Name)
    Else
        LT = aSheet.Name < bSheet.Name
    End If
End Function

double post

Just set Descending to True.

Or omit the Descending variable all together and change this line

If Not LT(.Sheets(j), .Sheets(i)) Then