VBA code to adjust row height for searched cells

Hi,
I have this code to find specific text entries in a ledger. It then bolds the cell. While I have located this cell, how can I then make the row active to adjust the row height?
thanks

Sub Boldtotalcostofsales()

'bolds total cost of sales title

Dim c As Range, firstaddress As String, ws As Worksheet, FindMe As String

FindMe = "Total Cost Of Sales"

'the value to find

For Each ws In ThisWorkbook.Worksheets

'loop through each worksheet

With ws.UsedRange

    Set c = .Find(FindMe, LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=True)

    If Not c Is Nothing Then

        firstaddress = c.Address

        Do

            c.Font.Bold = True
            

            'if found, make it bold

            Set c = .FindNext(c)
            

        Loop While Not c Is Nothing And c.Address <> firstaddress

    End If

End With

Next ws
    
End Sub

[

Try this

Sub Boldtotalcostofsales()

    'bolds total cost of sales title
    Dim c As Range, firstaddress As String, ws As Worksheet, FindMe As String
    
    'the value to find
    FindMe = "Total Cost Of Sales"
    
    For Each ws In ThisWorkbook.Worksheets
        'loop through each worksheet
        With ws.UsedRange
            Set c = .Find(FindMe, LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=True)

            If Not c Is Nothing Then
                firstaddress = c.Address

                Do
                    'if found, make it bold and adjust height
                    c.Font.Bold = True
                    c.Rows.AutoFit

                    Set c = .FindNext(c)
                Loop While Not c Is Nothing And c.Address <> firstaddress
            End If
        End With
    Next ws

End Sub

Thanks

Thank you Fredlo2010.
I set the row height to the desired height instead of the auto fit and worked.

Much appreciated.

Hi,

Change this

c.Rows.AutoFit

to

c.Rows.Height = 24

Thanks

Yes, did that thanks.
Just noticed another problem,
I want the rest of the row to be centre justified, I thought I had solved this with

        Do
            c.Font.Bold = True
            c.Rows.RowHeight = 22.25
            c.Rows.VerticalAlignment = xlCenter

            Set c = .FindNext(c)

but it doesn't seem to work.

Try,

c.EntireRow.VerticalAlignment = xlCenter

Ohh I like you!

Yes. Great stuff.