Trying to create a macro to update a large database easily

I can imagine a simple macro that would:

1) Cycle through every row on sheet2 to find the matching row on sheet1
2) Copy/Paste the entire row/values from sheet2 back into sheet1. Not a cell/by/cell comparison of any kind, just copy/paste values.
3) Anytime a searched value is NOT found on sheet1, it is added to the bottom of sheet1.

Option Explicit

Sub UpdateSheet1()
Dim ws2 As Worksheet, ws1 As Worksheet
Dim MyRng As Range, cell As Range, vFIND As Range

Set ws1 = ThisWorkbook.Sheets("Sheet1")         'edit this sheet name as needed
Set ws2 = ThisWorkbook.Sheets("Sheet2")         'edit this sheet name as needed

Set MyRng = ws2.Range("A2:A" & ws2.Range("A" & Rows.Count).End(xlUp).Row)

On Error Resume Next
For Each cell In MyRng
    Set vFIND = ws1.Range("A:A").Find(cell.Value, LookIn:=xlValues, LookAt:=xlWhole)
    If Not vFIND Is Nothing Then
        cell.EntireRow.Copy
        vFIND.PasteSpecial xlPasteValues
        Set vFIND = Nothing
    Else
        cell.EntireRow.Copy
        ws1.Range("A" & Rows.Count).End(xlUp).Offset(1).PasteSpecial xlPasteValues
    End If
Next cell

End Sub

Why not?

Sub UpdateSheet1()
    Dim ws2 As Worksheet, ws1 As Worksheet
    Dim MyRng As Range, cell As Range, vFIND As Range

    Set ws1 = ThisWorkbook.Sheets("Sheet1")         'edit this sheet name as needed
    Set ws2 = ThisWorkbook.Sheets("Sheet2")         'edit this sheet name as needed

    Set MyRng = ws2.Range("A2:A" & ws2.Range("A" & Rows.Count).End(xlUp).Row)

    On Error Resume Next
    For Each cell In MyRng
        Set vFIND = ws1.Range("A:A").Find(cell.Value, LookIn:=xlValues, LookAt:=xlWhole)
        If Not vFIND Is Nothing Then
            vFIND.Resize(, 10).Value = cell.Resize(, 10).Value
            Set vFIND = Nothing
        Else
            ws1.Range("A" & Rows.Count).End(xlUp).Offset(1).Resize(, 10).Value = cell.Resize(, 10).Value
        End If
    Next cell
End Sub

We can just add one line at the end I think will resolve that.

Option Explicit

Sub UpdateSheet1()
Dim ws2 As Worksheet, ws1 As Worksheet
Dim MyRng As Range, cell As Range, vFIND As Range

Set ws1 = ThisWorkbook.Sheets("Sheet1")         'edit this sheet name as needed
Set ws2 = ThisWorkbook.Sheets("Sheet2")         'edit this sheet name as needed

Set MyRng = ws2.Range("A2:A" & ws2.Range("A" & Rows.Count).End(xlUp).Row)

On Error Resume Next
For Each cell In MyRng
    Set vFIND = ws1.Range("A:A").Find(cell.Value, LookIn:=xlValues, LookAt:=xlWhole)
    If Not vFIND Is Nothing Then
        cell.EntireRow.Copy
        vFIND.PasteSpecial xlPasteValues
        Set vFIND = Nothing
    Else
        cell.EntireRow.Copy
        ws1.Range("A" & Rows.Count).End(xlUp).Offset(1).PasteSpecial xlPasteValues
    End If
Next cell
Application.CutCopyMode = False
End Sub

If that takes care of your original question, please select Thread Tools from the menu link above and mark this thread as SOLVED. Thanks.

@ Jerry

Check the last line you've added, please.